So sánh RRG chart trên amibroker và Optuma liệu có nên dùng.

Có ai hiểu và dùng cái chiêm tinh này chưa bạn?

 

Có gì đâu. Cứ theo chỉ dẫn đó làm là ra chiêm tinh là gì mình còn chưa bjo sdug nên k có phương án theo cách nghĩ của họ

 

Mục đích để làm gì còn chưa biết, thì sao mà làm

 

Này ko phải chiêm tinh. Hướng cp thôi bác nó quan niệm neuy 1 cp 3 ngày gần nhất mà nằm hướng đông bắc là cp mạnh . Hướng đông bâc cp đi lên.v
Còn chiêm tinh là cái gann học. Nó lấy giá xét lịch sử dự đoán tương lai. Này toàn mấy tay kỹ sư nguyên tử chế ra . Mấy bác ko hiểu ko nên chém thế. Nhiều bác tưởng thật lại ko hay

 

Bạn cho mình xài cái RRG này với. Mình đang sử dụng data của Fireant.

 

Chỉ có Price và Volume thôi chưa ngâm nên chưa biết tnao. Tên chiêm tinh chỉ là cái tên thôi

 

Thì bác đừng đưa hình tào lao cái phong thủy bên khựa. Bác ko hiểu thì đọc gann học thôi. Chứ em dò chiêm tinh ko có cái nào dùng cái hình đấy. Em toàn nghiêm túc nên ko thích đùa xàm

 

Cũng nói thật mình chưa bao có cơ hội sdung chiêm tinh nên chưa tìm hiểu. RRG bạn nói đầu bài top thì mình hoàn thiện và sdug trên ami lâu rồi. Gọi là vẽ photoshop chơi
Optuma mình chưa sdug bjo nhưng có RRG thì giờ có ami giải quyết xong lâu rồi. Có mỗi cái chiêm tinh nghe huyền bí chưa tìm hiểu.
Biết đâu giờ hết việc làm lại đi xin phần mền optuma ngâm cứu chiêm.tinh
Hình phong thủy trên để chỉ đường vẽ hướng gọi là bắc đông nam (nếu cần)

 

Bác

Bác là dân pro rùi. Có sức ảnh hưởng lớn. Các bác f0 hóng code nghe trúng trật thì không tốt thôi. Chủ yếu ý em thế thôi. Còn chiêm tinh ko huyền bí đâu nó cũng lâu đời lắm rồi từ thời wycofff đã có hệ phá

 

Cái đó là cái ranking mình tính ra đấy, nó sắp sếp từ 0-100, rồi chia theo màu, 100 mạnh nhất
Tính rồi đấy

 

Trong kênh youtube có link download, tuy nhiên bản cũ, chờ mình nâng cấp đã, chắc mai mốt mới có được.

 

Get Heading Values
V1 = JDKRS(INDEX=^VNINDEX:CSV 1).Heading;
//Define Ranges and assign values
N1 = IF(V1 > 337.5 or V1 < 22.5,1,0);
NE = IF(V1> 22.5 and V1 < 67.5,2,0);
E1 = IF(V1 > 67.5 and V1 < 112.5,3,0);
SE = IF(V1 > 112.5 and V1 < 157.5,4,0);
S1 = If(V1 > 157.5 and V1 < 202.5,5,0);
SW = IF(V1 > 202.5 and V1 < 247.5,6,0);
W1 = IF(V1 > 247.5 and V1 < 292.5,7,0);
NW = IF(V1 > 292.5 and V1 < 337.5,8,0);
//Sum values
N1+NE+E1+SE+S1+SW+W1+NW
gởi các bác cách tính hướng trong optuma

 

cái E-dragon kia e cài xong rồi mà k thấy hướng dẫn sử dụng bác ơi

 

Trong kênh youtube có đó bạn, cái RRCs thì chưa update

 

Bác phải bác stockpro trc kia hay share phần mềm với sách phải không bác. Tầm năm 2006-2007

 

Cho mình xin links youtube với bạn.
Fireant nó cung cấp RRG mà không đúng ae ơi.
Đây là cái họ cài cho mình, mình xem sao nó bị sai ngày

 

Cái của Fireant lấy code của bản public giông như các bạn trên này chia sẽ, chỉnh sửa lại màu với pick data.
https://youtu. be/rdwcS8AUT-w (bỏ dấu cách).
Cái RRCs mình chưa update.

 

Đã cập nhật bản mới rồi bạn nhé.
Vào parameter để chỉnh thông số, chuyển list muốn xem (có làm sẵn cho data cp68), chạy analysis để tính điểm xem con nào mạnh.

 

Mình đang dùng amibroker lấy dữ liệu từ Fireant. Có cách nào mình cài RRG của bạn vào amibroker của mình ko bạn ơi

 

_SECTION_BEGIN( "PPO-Rotational Chart" );

SetChartOptions( 1, chartDisableTooltips, gridFlags = 0 );

_SECTION_BEGIN( "Tickers && Benchmark" );
benchmark = ParamStr( "Benchmark", "VNINDEX" ); // co the thay bang: HNXINDEX, UPINDEX; ^VNINDEX (neu su dung du lieu cua cophieu68)
tickers = ParamStr( "Tickers", "TCB,ACB,VCB,NVB,KLB,VPB,VIB" );
_SECTION_END();

_SECTION_BEGIN( "Tailing" );
tbar = Param( "Tailing Bar", 10, 1, 100, 1 );
thick = Param( "Thickness", 1, 0.5, 1.5, 0.05 );
colorTail = ParamColor( "BaseColor", colorBlack );
_SECTION_END();

_SECTION_BEGIN( "Lookback Bars" );
shortLen = Param( "ShortLen", 10, 5, 100, 1 ); // co the thu thay doi sang 12
longLen = Param( "LongLen", 30, 5, 300, 1 ); // co the thu thay doi sang 26
signalLen = Param( "SignalLen", 9, 5, 30, 1 );
_SECTION_END();

_SECTION_BEGIN( "Margins" );
topMargin = Param( "Top", 15, 10, 100, 1 );
bottomMargin = Param( "Bottom", 15, 10, 100, 1 );
leftMargin = Param( "Left", 30, 10, 100, 1 );
rightMargin = Param( "Right", 30, 10, 100, 1 );
_SECTION_END();

SetChartBkGradientFill( colorGrey50, colorGrey40 );

pxl = Status( "pxchartleft" ) + leftMargin;
pxr = Status( "pxchartright" ) - rightMargin;
pxt = Status( "pxcharttop" ) + topMargin;
pxb = Status( "pxchartbottom" ) - bottomMargin;
pxw = ( pxr - pxl ) / 2;
pxh = ( pxb - pxt ) / 2;
xm = pxl + pxw;
ym = pxt + pxh;

base = benchmark;
listSym = StrTrim( tickers, " " );

// get rs or rm (momentum)
function getrs( sc, t )
{
bc = Foreign( base, "C" );
sbr = sc / bc;

rs1 = MA( sbr, shortLen ); // short period
rs2 = MA( sbr, longLen ); // long period

rs = 100 * ( ( rs1 - rs2 ) / rs2 + 1 );

rm1 = MA( rs, 1 );
rm2 = MA( rs, signalLen );

rm = 100 * ( ( rm1 - rm2 ) / rm2 + 1 );

return IIf( t, rs , rm ) - 100;
}

// draw position on the chart
function drawpos( x, y, sym, text )
{
rsl = VarGet( "rsl" );
rsh = VarGet( "rsh" );
rml = VarGet( "rml" );
rmh = VarGet( "rmh" );

xx = pxl + pxw + x * ( pxw / ( Max( rsh, -rsl ) * 1.08 ) );
yy = pxb - pxh - y * ( pxh / ( Max( rmh, -rml ) * 1.08 ) );

xp = Nz( VarGet( "xp" + sym ), xx );
yp = Nz( VarGet( "yp" + sym ), yy );

VarSet( "xp" + sym, xx );
VarSet( "yp" + sym, yy );

GfxMoveTo( xp, yp );
GfxLineTo( xx, yy );

GfxCircle( xx, yy, IIf( text == "", 1.5, 1.5 ) );

if( text != "" ) GfxTextOut( sym, xx + 6 , yy + 3 );
}

GfxSelectFont( "Tahoma", 10, 500 );

if( listSym != "" )
{
GfxSetZOrder( 5 );

for( i = 0; ( sym = StrExtract( listSym, i ) ) != ""; i++ )
{
TimeFrameSet( Interval( 0 ) );

SetForeign( sym, 1 );
//rs = getrs( (C + H + L)/3, 1 );
//rm = getrs( (C + H + L)/3, 0 );
rs = getrs( C, 1 );
rm = getrs( C, 0 );

for( ii = BarCount - tbar; ii < BarCount; ii++ )
{
rs_ = rs[ ii ];
rm_ = rm[ ii ];

rsh = Nz( VarGet( "rsh" ), rs_ );

if( rs_ >= rsh )
VarSet( "rsh", rs_ );

rsl = Nz( VarGet( "rsl" ), rs_ );

if( rs_ <= rsl )
VarSet( "rsl", rs_ );

rmh = Nz( VarGet( "rmh" ), rm_ );

if( rm_ >= rmh )
VarSet( "rmh", rm_ );

rml = Nz( VarGet( "rml" ), rm_ );

if( rm_ <= rml )
VarSet( "rml", rm_ );
}

RestorePriceArrays( False );
}

color = colorTail;

for( i = 0; ( sym = StrExtract( listSym, i ) ) != ""; i++ )
{
TimeFrameSet( Interval( 0 ) );

SetForeign( sym, 1 );
//rs = getrs( (C + H + L)/3, 1 );
//rm = getrs( (C + H + L)/3, 0 );
rs = getrs( C, 1 );
rm = getrs( C, 0 );

widthLine = thick * Min( ( HighestVisibleValue( abs( MA( rs, longLen ) ) ) + HighestVisibleValue( abs( MA( rm, longLen ) ) ) ) / 2, 2 );

GfxSetBkMode( 1 ); // transparent
GfxSetTextAlign( 6 ); // center alignment

color += i;
GfxSetTextColor( color );
GfxSelectPen( color, widthLine );

for( ii = BarCount - tbar; ii < BarCount; ii++ )
{
drawpos( rs[ ii ], rm[ ii ], sym, WriteIf( ii == BarCount - 1, sym, "" ) );
}

RestorePriceArrays( False );
}
}

Title = "";

GfxSetTextColor( colorYellow );
strTemp = StrFormat( "Benchmark: %s, TF: %s", base, Interval( 2 ) );
GfxSetTextAlign( 0 ); // right alignment
GfxTextOut( strTemp, pxl, topMargin / 3 );

strDisplay = "PPO-Rotational Chart";
GfxSetTextAlign( 2 ); // right alignment
GfxTextOut( strDisplay, pxr, topMargin / 3 );

GfxSetZOrder( 0 );
lead = "LEADING";
weak = "WEAKENING";
lag = "LAGGING";
improve = "IMPROVING";

GfxFillSolidRect( pxr, pxt, xm, ym, ColorBlend( colorBrightGreen, colorWhite, 0.69 ) );
GfxFillSolidRect( pxl, pxt, xm, ym, ColorBlend( colorBlue, colorWhite, 0.69 ) );
GfxFillSolidRect( pxr, pxb, xm, ym, ColorBlend( colorYellow, colorWhite, 0.69 ) ); //colorYellow
GfxFillSolidRect( pxl, pxb, xm, ym, ColorBlend( colorOrange, colorWhite, 0.69 ) ); //colorOrange

GfxSetBkMode( 1 ); // transparent
GfxSetTextAlign( 2 ); // right alignment
GfxSetTextColor( colorBlue );
GfxSelectFont( "Tahoma", 11, 700 );
GfxTextOut( lead, pxr, pxt );
GfxTextOut( weak, pxr, pxb - 15 );
GfxSetTextAlign( 0 ); // left alignment
GfxTextOut( lag, pxl, pxb - 15 );
GfxTextOut( improve, pxl, pxt );

GfxSetTextAlign( 0 ); // left alignment
GfxSetTextColor( colorWhite );
GfxSelectFont( "Tahoma", 10, 500 );

if( listSym != "" )
{
totalSymbols = StrCount( listSym, "," ) + 1;
GfxTextOut( "Tickers[" + totalSymbols + "]: " + listSym, pxl, pxb );
}

GfxSelectPen( colorBlueGrey, 1, 2 );
GfxMoveTo( pxl, ym );
GfxLineTo( pxr, ym );
GfxMoveTo( xm, pxt );
GfxLineTo( xm, pxb );

_SECTION_END();

của bạn đây, mình chỉnh thành 1 phiên bản gọn nhất để ai cũng có thể dùng được